Hack Taskbar Windows

Masih seputar Tips - Trik Visual Basic tentunya, kali ini saya coba membahas tentang Hack Taskbar Windows yaitu bagaimana caranya Menghilangkan Taskbar, Menghilangkan Button Start serta cara Menghilangkan Waktu / Tanggal yang ada pada Sistray Area tapi sobat tidak perlu kwatir pasti ada pengembalian atau reset kedefault semula. Mungkin sobat masih ngambang tentang penjelasan saya diatas, dengan gambar dibawah ini mudah-mudahan sobat bisa paham maksud dari Tips - Trik ini.


Okelah kalau begitu saya akan lanjutkan tentang coding nya bagi yang tertarik silakan ikuti langkah - langkah berikut ...

• Tambahkan tiga buah CommandButton diproject, masing-masing dengan nama : cmdTaskbar, cmdStartButton dan cmdSystemClock
• Tambahkan satu buah Module

Tempatkan Coding dibawah ini pada Module

Public Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function GetDlgItem Lib "user32" (ByVal hDlg As Long, ByVal nIDDlgItem As Long) As Long
Public TaskBarStyle As Boolean, StartButtonStyle As Boolean, SystemClockStyle As Boolean
Public Const StartButtonID = &H130
Public Const SystemClockID = &H12F
Public Const SW_HIDE = 0
Public Const SW_SHOW = 5

Public Sub HideTaskBar()
Dim wClassName As String
Dim hwndTaskbar As Long
wClassName = "Shell_TrayWnd"
hwndTaskbar = FindWindow(wClassName, vbNullString)
If TaskBarStyle = False Then
Form1.cmdTaskbar.Caption = "Show Taskbar"
ShowWindow hwndTaskbar, SW_HIDE
TaskBarStyle = True
Else
Form1.cmdTaskbar.Caption = "Hide Taskbar"
ShowWindow hwndTaskbar, SW_SHOW
TaskBarStyle = False
End If
End Sub


Public Sub HideStartButton()
Dim wClassName As String
Dim hwndTaskbar As Long, hwndStartbutton As Long
wClassName = "Shell_TrayWnd"
hwndTaskbar = FindWindow(wClassName, vbNullString)
hwndStartbutton = GetDlgItem(hwndTaskbar, StartButtonID)
If StartButtonStyle = False Then
Form1.cmdStartButton.Caption = "Show Start Button"
ShowWindow hwndStartbutton, SW_HIDE
StartButtonStyle = True
Else
Form1.cmdStartButton.Caption = "Hide Start Button"
ShowWindow hwndStartbutton, SW_SHOW
StartButtonStyle = False
End If
End Sub

Public Sub HideSystemClock()
Dim wClassName As String
Dim hwndTaskbar As Long, hwndSystemClock As Long
wClassName = "Shell_TrayWnd"
hwndTaskbar = FindWindow(wClassName, vbNullString)
hwndSystemClock = GetDlgItem(GetDlgItem(hwndTaskbar, SystemClockID), SystemClockID)
If SystemClockStyle = False Then
Form1.cmdSystemClock.Caption = "Show System Colock"
ShowWindow hwndSystemClock, SW_HIDE
SystemClockStyle = True
Else
Form1.cmdSystemClock.Caption = "Hide System Clock"
ShowWindow hwndSystemClock, 5
SystemClockStyle = False
End If
End Sub

Public Sub SetToDefault()
TaskBarStyle = True
StartButtonStyle = True
SystemClockStyle = True
HideTaskBar
HideStartButton
HideSystemClock
End Sub

Tempatkan Coding dibawah ini pada Form Project

Private Sub cmdStartButton_Click()
HideStartButton
End Sub

Private Sub cmdSystemClock_Click()
HideSystemClock
End Sub

Private Sub cmdTaskbar_Click()
HideTaskBar
End Sub

Private Sub Form_Load()
cmdTaskbar.Caption = "Hide TaskBar"
cmdStartButton.Caption = "Hide Start Button"
cmdSystemClock.Caption = "Hide System Clock"
End Sub

Private Sub Form_Unload(Cancel As Integer)
SetToDefault
End Sub

Mudah - mudahan Tips ini ada mamfaat nya bagi kita semua dan VB Developer khususnya, semoga tidak digunakan untuk menjahili teman atau orang lain. Kalau ada kesempatan dan waktu kita akan ketemu dengan Tips - Trik berikutnya .. terima kasih.

READ MORE - Hack Taskbar Windows

Membuat Auto Complete pada Combo Box (Visual Basic)

Pada postingan kali ini saya akan membahas kembali mengenai Visual Basic yaitu Membuat Auto Complete pada Combo Box, maksud Auto Complete disini adalah Melengkapi Teks secara Otomatis pada saat sedang melakukan pengetikan ke data yang mendekati atau yang dinginkan, dengan catatan apabila data tersebut ada pada list data Combo Box tersebut.

Tip ini sangat berguna apabila menggunakan combobox yang di dalamnya terdiri atas ratusan bahkan ribuan data. User (pengguna/pemakai program) akan kesulitan jika harus memilih satu per satu menggunakan scroll combobox ke bawah hingga data yang diinginkan ketemu. Dengan adanya tip ini, user cukup hanya mengetikkan beberapa karakter awal, dan program akan otomatis melengkapinya, sehingga tidak perlu mengetik sampai akhir. Nah bagi yang berkenan untuk Tip ini silahkan ikuti langkah-lah berikut

• Buatlah Project Baru Standart Exe
• Tambahkan 1 buah ComboBox Style : Dropdown Combo
• Tambahkan 1 buah Module

Ketik Coding berikut pada Module:

Option Explicit

Const CB_FINDSTRING = &H14C

Public Declare Function SendMessage Lib "user32" _
Alias "SendMessageA" (ByVal hwnd As Long, _
ByVal wMsg As Long, ByVal wParam As Long, _
lParam As Any) As Long

Public Enum EnumKarakter
Asli = 0
Ubah = 1
End Enum

Public Function AutoComplete( _
cbCombo As ComboBox, _
sKeyAscii As Integer, _
Optional bUpperCase As Boolean = True, _
Optional cCharacter As EnumKarakter = Asli) _
As Integer
Dim lngFind As Long, intPos As Integer
Dim intLength As Integer, tStr As String
With cbCombo
If sKeyAscii = 8 Then
If .SelStart = 0 Then Exit Function
.SelStart = .SelStart - 1
.SelLength = 32000
.SelText = ""
Else
intPos = .SelStart
tStr = .Text
If bUpperCase = True Then
.SelText = UCase(Chr(sKeyAscii))
Else
.SelText = (Chr(sKeyAscii))
End If
End If

lngFind = SendMessage(.hwnd, CB_FINDSTRING, 0, _
ByVal .Text)
If lngFind = -1 Then
Exit Function
Else
intPos = .SelStart
intLength = Len(.List(lngFind)) - Len(.Text)
If cCharacter = Ubah Then
.SelText = .SelText & Right(.List(lngFind), _
intLength)
Else
.Text = .List(lngFind)
End If
.SelStart = intPos
.SelLength = intLength
End If
End With
End Function

' Ketik Coding diberikut pada Form

Option Explicit

Private Sub Combo1_KeyPress(KeyAscii As Integer)
KeyAscii = AutoComplete(Combo1, KeyAscii, False, Asli)
End Sub

Private Sub Form_Load()
Call AddData
End Sub

Private Sub AddData()
With Combo1
.Clear
.AddItem "Ana Lestari"
.AddItem "Budi Setiawan"
.AddItem "Eka Syahputra"
.AddItem "Wahyu Perdana"
.AddItem "Blog walking"
.AddItem "Terserah"
End With
End Sub

Kemudian Run (jalankan) Program atau tekan F5, lalu pada combobox coba ketik huruf a , maka secara Otomatis teks pada combobox akan menjadi Ana Lestari. Semoga Tip ini ada mamfaat nya bagi kita semua...

READ MORE - Membuat Auto Complete pada Combo Box (Visual Basic)

Mencari Selisih Tanggal (Visual Basic 6)

Persiapan yang dilakukan :

• Buatlah Project Baru (Standard exe)
• Tambahkan :
• 3 Label
• Label1 (Caption : Mencari Selisih Tanggal)
• Label2 (Caption : Lahir :)
• Label3 (Caption : Umur Anda)
• 1 Buah Frame ------> Caption : Masukan Tanggal Lahir
  
• 3 Buah ComboBox ----> Style : 2 - Dropdown List
• 1 Buah Command Button

yang kurang lebih penampakannya seperti gambar dibawah ini

kemudian ketik Coding dibawah ini pada Form

Option Explicit

Private Sub showTanggal()
Dim i As Byte
For i = 1 To 31
Combo1.AddItem Format(i, "00")
Next i
Combo1.ListIndex = 0
End Sub

Private Sub showBulan()
Dim i As Byte
For i = 1 To 12
Combo2.AddItem Format(i, "00")
Next i
Combo2.ListIndex = 0
End Sub

Private Sub showTahun()
Dim i As Integer
For i = 1950 To Year(Now)
Combo3.AddItem i
Next i
Combo3.ListIndex = 0
End Sub

Private Sub Command1_Click()
Dim sLahir As String
sLahir = Combo1 + "/" + Combo2 + "/" + Combo3
If IsDate(sLahir) = True Then
Label3.Caption = "Umur anda sekarang : " & SelisihTanggal(CDate(sLahir), Date)
Else
MsgBox "Tanggal nya salah coy", 48, "Info"
Combo1.SetFocus
End If
End Sub

Private Sub Form_Load()
showTanggal
showBulan
showTahun
End Sub

Private Function SelisihTanggal(ByVal TanggalAwal As _
Date, ByVal TanggalAkhir As Date) As String

Dim Tahun As Integer, Sisa As Integer
Dim SelisihBulan As Integer
On Error GoTo pesan
SelisihBulan = DateDiff("m", TanggalAwal, TanggalAkhir)
Tahun = SelisihBulan \ 12
Sisa = SelisihBulan Mod 12
SelisihTanggal = Tahun & " Tahun " & Sisa & " Bulan"
Exit Function
pesan:
MsgBox "Tipe Tanggal Salah!", vbCritical, "Error TAnggal"
End Function

Mudah2an ada manfaat nya bagi rekan2.

READ MORE - Mencari Selisih Tanggal (Visual Basic 6)

Membuat Caption Label Bergerak Dengan Visual Basic

Tips kali ini masih seputar Visual Basic yaitu Membuat Caption Label Bergerak , maksudnya bisa berjalan-jalan (smoga aja gak kesasar yah ^-^) kalau di Html istilah nya Marquee (kalo gak salah), mudah-mudahan yang saya maksud bisa ngerti yah, kalo gak ngerti di mengertiin aja deh , Nah bagi yang berminat silakan ikuti langkah-langkah dibawah ini, Persiapan :

- Buat Project baru Standart Exe
- Tambahkan 1 buah Control Timer (Timer1) Property yang diset :
Enable = True, Interval = 100
- Satu Buah Control Label (Label1)

Ketik Coding dibawah ini pada Form Project

Dim Pos As Integer, StartPos As Integer, Lengh As Integer, iTeks As Integer
Dim MyTeks As String

Private Sub Form_Load()
iTeks = 1
End Sub

Private Sub Timer1_Timer()
Pos = Pos + 1
If iTeks = 1 Then
MyTeks = "Ini adalah Contoh ..."
ElseIf iTeks = 2 Then
MyTeks = "Pembuatan Label Berjalan"
ElseIf iTeks = 3 Then
MyTeks = "Dengan Visual Basic"
End If
StartPos = Len(MyTeks)
Lengh = StartPos - Pos
If Lengh = 0 Then
If iTeks = 1 Then
iTeks = 2
ElseIf iTeks = 2 Then
iTeks = 3
ElseIf iTeks = 3 Then
iTeks = 1
End If
Pos = 0 - StartPos
End If
Label1 = Right(MyTeks, Lengh)
End Sub

Mudahkan gak ribet , Sekarang Coba sobat jalan kan Project nya (Tekan F5) Caption pada label1 akan berjalan-jalan dan tulisannya bergantian tapi hati-hati sob jangan sampai labelnya kesasar gak tau pulang ^-^

READ MORE - Membuat Caption Label Bergerak Dengan Visual Basic